#
# v-emu-ivsat.awk - emulate IrfanView saturation correction
#   by uratan! 2021.12.15
#
	#
	# usage: pass output of "ppmtoppm -plain" like:
	#  +-------------------------------------------------------
	#  |ppmANY ... | ppmtoppm -plain | awk -v sat=32 -f v-emu-ivsat.awk \
	#  |  | ppmtoppm > result.ppm
	#  +-------------------------------------------------------
	#
BEGIN {
	state = 1;
	#sat = 0;	# saturation level, [-255, 255], give this from command line
}
{
		#
		# load PPM-ASCII image
		#
	if(state == 1) {
			#
			# wait for the file type
			#
		type = $1;
		if(type == "P3") {
			state++;		# expect PPM, ASCII only
		} else {
			;				# ignore anything else
		}
	}
	else if(state == 2) {
			#
			# wait for width and height
			#
		width  = $1;
		height = $2;
		x = 0;
		y = 0;
		state++;
	}
	else if(state == 3) {
			#
			# wait for maxV
			#
		maxV = $1;
		state++;
	}
	else if(state == 4) {
			#
			# feed pixmap data
			#
		i = 1;
		while(i <= NF) {
			pR[x,y] = $(i++);
			pG[x,y] = $(i++);
			pB[x,y] = $(i++);
			x++;
			if(x >= width) {
				y++;
				x = 0;
			}
		}
	}
	else {
		;		# ignore any
	}
}
END {
	if(state != 4) {
		print "error!";
	}
	else {
		#
		# issue saturation correction
		#
		for(y=0; y<height; y++) {
			for(x=0; x<width; x++) {

	RR = pR[x,y];
	GG = pG[x,y];
	BB = pB[x,y];

	#
	# all RGB elements reachs to this luminance when (sat = -256)
	#
	YY = int( (77 * RR + 151 * GG + 28 * BB) / 256 );

	#
	# so simply divide the difference by saturation distance
	#   (caution: when minimum ratio -255, some color)
	#   (         remained, not fully grayscaled     )
	#
	RR = int( RR + sat * (RR - YY) / 256.0 +0.499);
	GG = int( GG + sat * (GG - YY) / 256.0 +0.499);
	BB = int( BB + sat * (BB - YY) / 256.0 +0.499);

	#
	# clamp them when over the range
	#
	if(RR > 255) { RR = 255; } else if(RR < 0) { RR = 0; }
	if(GG > 255) { GG = 255; } else if(GG < 0) { GG = 0; }
	if(BB > 255) { BB = 255; } else if(BB < 0) { BB = 0; }

	pR[x,y] = RR;
	pG[x,y] = GG;
	pB[x,y] = BB;

			}
		}

		#
		# output them with PPM-ASCII
		#
		printf("%s\n", "P3");			# ppm, ascii
		printf("%d %d\n", width, height);
		printf("%d\n", maxV);
		for(y=0; y<height; y++) {
			for(x=0; x<width; x++) {
				printf("%d %d %d\n", pR[x,y], pG[x,y], pB[x,y]);
			}
		}
	}
}

	#
	# FYI-1: about float to int conversion
	#
	# ceil(x)  - x 以上の最小の整数
	# floor(x) - x 以下の最大の整数
	# round(x) - x を「四捨五入」した整数
	# trunc(x) - |x| 以下の最大の整数に符号をつけたもの
	#
	# int() of AWK - returns the nearest interger to X,
	#                located between X and zero,
	#                and truncated towaerd zero.
	#
	#  ceil()   21111111111000000000011111111112222222222
	#  floor()  22222222221111111111000000000011111111112
	#  round()  22222111111111100000000001111111111222222 (? maybe...)
	#  trunc()  21111111111000000000000000000011111111112    <== int() of AWK
	#         --+---------+---------+---------+---------+-->
	#          -2        -1         0         1         2
	#

	#
	# FYI-2: about grayscale conversion
	#
	# ppmtopgm uses:  (MAXVAL <= 255)
	#   YY = int( (77 * RR + 150 * GG + 29 * BB + 128) / 256 );
	#
	# 'Convert to Grayscale' of IrfanView uses:
	#   YY = int( 0.30 * RR + 0.59 * GG + 0.11 * BB + 0.5 );
	#